;XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
;
; Create cowave.in from arguments
;
; Patrick Robert, CETP, February 2007
;
;XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX

  PRO scmwf_define_calparam, RFF_path, Cal_path, Julsec1,Julsec2, $
                             nbp,fdet,fcut,fmin,fmax,step
                             
; RFF_path  : path of RFF file to read
; Cal_path  : path of cal directory
; Julsec1   : 1970 Jul. sec. of starting time
; Julsec2   : 1970 Jul. sec. of ending time
; nbp       : number of point of the cal window
; fdet      : detrend frequency; if set to 0., -> classic despin
; fcut      : low cut-off frequency (no cal under this limit)
; fmin, fmax: limits for a filtering in a fixed system (for step >4)
; step      : level of calibration, 1-7 (4=SSL)
                               
; *** Example of cowave.in file 

; ./tha_scmwf_L1.rff
; ./cal
; 2037 11 30  # day-month-year of period
; 21 26 00.0  # Hour-min-sec   of start period (real double sec)
;  15.        # Duration of the time period (min)
; 256         # Number of point of the window (256-65536)
; 0.          # detrend frequency, 0.=classic despin
; 0.1         # Frequency cut-off for calibration
; 0. 0.       # Min/Max frequencies for filtering (0. 0. => full band)
; 4           # Processing levels asked (1-4)

; *** this file can be created by the following command:
;     (without the comments)

; scmwf_define_calparam, './tha_scmwf_L1.rff', './cal', Julsec1,Julsec2, $
;                         256, 0., 0.1, 0., 0., 4

; *** compute day-month-year of period and Hour-min-sec of start period 

  isodatim= Julsec_to_isodatim(Julsec1, 8)
  decode_isodatim, isodatim,year,month,day,hour,min,secdbl
  duration= (Julsec2 -Julsec1)/60.D0

; *** create cowave.in

  GET_LUN, unit

  PRINT, ' '
  PRINT, FORMAT='(a,i4,a)', $
         'Creating cowave.in on unit',unit,', Please wait...'
  OPENW, unit, 'cowave.in'

  PRINTF, unit, format='(a)'              , RFF_path
  PRINTF, unit, format='(a)'              , Cal_path
  PRINTF, unit, format='(i4,2i3.2)'       , year,month,day
  PRINTF, unit, format='(i2.2,i3.2,f10.6)', hour,min,secdbl
  PRINTF, unit, format='(f10.5)'          , duration
  PRINTF, unit, format='(i6)'             , nbp
  PRINTF, unit, format='(f9.4)'           , fdet
  PRINTF, unit, format='(f9.4)'           , fcut
  PRINTF, unit, format='(2f9.4)'          , fmin,fmax
  PRINTF, unit, format='(i2)'             , step

  FREE_LUN, unit

  PRINT, FORMAT='(a)','Done...'

  END

; XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX