;+
;	Batch File: THM_CRIB_EFI
;
;	Purpose:  Demonstrate the loading, calibration, and plotting
;		of THEMIS EFI data.
;
;	Calling Sequence:
;	.run thm_crib_fbk, or using cut-and-paste.
;
;	Arguements:
;   None.
;
;	Notes:
;	None.
;
; $LastChangedBy: jwl $
; $LastChangedDate: 2009-06-11 14:54:28 -0700 (Thu, 11 Jun 2009) $
; $LastChangedRevision: 6149 $
; $URL $
;-

; EFI waveform data example.
tplot_title = 'THEMIS EFI Waveform Examples'
tplot_options, 'title', tplot_title
tplot_options, 'xmargin', [ 15, 10]
tplot_options, 'ymargin', [ 5, 5]

timespan, '2008-05-15', 1.0, /day
thm_load_efi, level=1, suffix='_raw',  type='raw', /get_support
loadct2, 39

; the following are optional, since they should be set
; by thm_load_efi as the default plotting options (dlimits).
; you can use these as a starting point if you want to modify the labels/colors.
;options, 'th?_v??_raw', 'colors', [ 1, 2, 3, 4, 5, 6]
;options, 'th?_v??_raw', 'labels', [ 'V1', 'V2', 'V3', 'V4', 'V5', 'V6']
;options, 'th?_v??_raw', 'labflag', 1

;options, 'th?_e??_raw', 'colors', [ 2, 4, 6]
;options, 'th?_e??_raw', 'labels', [ 'e12', 'e34', 'e56']
;options, 'th?_e??_raw', 'labflag', 1

tplot, [ 'th[cde]_vaf_raw', 'th[cde]_eff_raw']

print, 'The plot shows raw data for all probe for which the booms have
print, 'been deployed as of 2007-06-30.'
print,'Enter ".c"  to print the contents of DLIMITS.DATA_ATT structure for'
print,'"tha_vaf_raw", and "tha_eff_raw".'
stop

get_data,'tha_vaf_raw',dlimits=dl
help,dl.data_att,/st
get_data,'tha_eff_raw',dlimits=dl
help,dl.data_att,/st
print,'Enter ".c" to zoom in.'
stop

tr = timerange()
tlimit, [ tr[0] + 10d*3600 + 10d*60 , tr[0] + 13d*3600 + 56d*60 ]    ;10:10:00 to 13:56:00

print, 'zoomed into a period where all satellites have some good data  '
stop

;; state data needed by thm_load_fgm, which is needed for dot0 quantities.
thm_load_state , /get_support

thm_cal_efi, /verbose, in_suffix='_raw', ontheflyedcoffset = edcoffset

tplot, [ 'thc_vaf_raw', 'thc_vaf', 'thc_eff_raw', 'thc_eff', $
         'thc_eff_0', 'thc_eff_dot0' ]

print,'Enter ".c"  to print the contents of DLIMITS.DATA_ATT structure for'
print,'"thc_vaf", and "thc_eff" (note updated and additional fields).'
stop

get_data,'tha_vaf',dlimits=dl
help,dl.data_att,/st
get_data,'tha_eff',dlimits=dl
help,dl.data_att,/st
print,'Enter ".c" view particle burst data.'
stop

; unfortunately, no vap or vaw at this time for thc, only tha and thb
tlimit, /full
tplot, [ 'tha_vap_raw', 'tha_vap', 'tha_efp_raw', 'tha_efp', $
         'tha_efp_0', 'tha_efp_dot0' ]
print, 'particle burst'
print, 'use the mouse to zoom in'
tlimit

stop

tplot, [ 'tha_vaw_raw', 'tha_vaw', 'tha_efw_raw', 'tha_efw', $
         'tha_efw_0', 'tha_efw_dot0' ]
print, 'wave burst occurs within particle burst'
print, 'use the mouse to zoom in'
tlimit


end